Hallo,

Wie wir wissen, soll keiner mit administrator Rechte auf dem Pc arbeiten,da dann Fremde Programme auf dem Rechner installiert werden können.Einfach in der Systemsteuerung--->Benutzerkonto ein neues Konto eröffnen und diesem eingeschrängte Rechte geben.

So ,doch muss man vieleicht mal ein Programm installieren, oder eine Soft deinstallieren, in der registry änderen, da man dieses dann nur mit Administrator-Rechte erledigen kann.

Hier sind 3 Dateien die unter XP ein super Tool ergeben:

das ist der Start, einfach in eine textdatei kopieren und dann admin_menu.bat
nennen.

echo off
rem ======================================================================
::
:: ADMIN MENU (Windows XP)
::
::
rem ----------------------------------------------------------------------

rem ======================================================================

rem ----------------------------------------------------------------------
:: CONFIG
rem ----------------------------------------------------------------------

set fConfig="admin_menu_config.txt"


rem ----------------------------------------------------------------------
:: START
rem ----------------------------------------------------------------------

cd /d %0\..
if NOT EXIST %fConfig% goto errorNoConfig
net user "%USERNAME%" 2> nul | find /i "admin" | find /i /v "name" >nul
if %ERRORLEVEL%==0 goto menu


rem ----------------------------------------------------------------------
:: LOGON
rem ----------------------------------------------------------------------

title Admin logoin
echo.
echo --- you need login:
echo.
echo with admins rigths functional.
echo No Admin Rights.
echo.
FOR /F "delims== tokens=1,2 " %%a IN ('findstr "^set\ sAdminUser=" %fConfig%') do set sAdminUser=%%b
if NOT "%sAdminUser%"=="" goto testAdmin

:enterAdmin
set sAdminUser=
set /p sAdminUser=Adminstrator-User (logout with ENTER):
if "%sAdminUser%"=="" goto end

:testAdmin
net user "%sAdminUser%" 2> nul | find /i "admin" | find /i /v "name" >nul
if %ERRORLEVEL%==0 goto runas
echo Sorry, "%sAdminUser%" is not Admin.
echo.
goto enterAdmin

:runas
runas /user:%sAdminUser% %0
if NOT %ERRORLEVEL%==0 pause
goto end


rem ----------------------------------------------------------------------
:: MAIN
rem ----------------------------------------------------------------------

:menu
rem ------------------------------------------------------------
:: show the menu
rem ------------------------------------------------------------
cls
color cf && title ***** ADMIN-MENU *****
echo.
echo ***** ADMIN-MENU *****
echo.
echo the following programs runs under users "%username%" account:
echo.
FOR /F "delims=: tokens=1,2 " %%a IN ('findstr "^[A-Za-z0-9].*: ^-:" %fConfig%') do echo. %%a - %%b
echo.

rem ------------------------------------------------------------
:: wait for user input
rem ------------------------------------------------------------
set sMenu=
set /p sMenu=Your selection [Enter]; logout with enter:
if "%sMenu%"=="" goto end

rem ------------------------------------------------------------
:: start the program
rem ------------------------------------------------------------
echo.
echo.
set sProgram=
FOR /F "delims=: tokens=1,2* " %%a IN ('findstr /i "^%sMenu%:" %fConfig%') do set sProgram=%%c
echo starte %sProgram%...
echo.
%COMSPEC% /c %sProgram%
if NOT %ERRORLEVEL%==0 pause
goto menu



:errorNoConfig
echo --- ERROR:
echo no file %fConfig% found.
echo the file was searched in:
cd
echo.
echo press any Key to logout.
pause >nul
goto end


rem ----------------------------------------------------------------------
:: END
rem ----------------------------------------------------------------------

:end
echo -- THE END.


rem ======================================================================
:: ENDE
rem ======================================================================


hier die Zweite ,das ist die konfiguration in der beliebig erweitert werden kann diese in eine textdatei kopieren und admin_menu_config.txt nennen.

# ======================================================================
#
# CONFIG FOR ADMIN_MENU
#
# ----------------------------------------------------------------------
# 2005-03-27
# ======================================================================


# ----------------------------------------------------------------------
# lokaler Adminstrator (muss nicht vorgegeben werden)
# ----------------------------------------------------------------------
set sAdminUser=


# ----------------------------------------------------------------------
# Syntax
# keyword:Display:command
# ----------------------------------------------------------------------
1:My_Computer:""%ProgramFiles%\Internet Explorer\IEXPLORE.EXE"" ::{20D04FE0-3AEA-1069-A2D8-08002B30309D}
# oder als Variante mit normalem Explorer:

# 1:Explorer:explorer.exe ::{20D04FE0-3AEA-1069-A2D8-08002B30309D}

2:Control_Panal:""%ProgramFiles%\Internet Explorer\IEXPLORE.EXE"" ::{20D04FE0-3AEA-1069-A2D8-08002B30309D}\::{21EC2020-3AEA-1069-A2DD-08002B30309D}

3:Computer_Management:%windir%\system32\mmc.exe /s %windir%\system32\compmgmt.msc
4:Symentec_Console:""%ProgramFiles%\Symantec\Symantec System Center\symantec system center.msc""


5:DOS-cmd:%comspec%
-:- - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
6:Autoruns (www.sysinternals.com):E:\Tools\Autoruns\autoruns.exe
-:- - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
#M:Menu konfigurieren:notepad admin_menu_config.txt


# ----------------------------------------------------------------------
# EOF
# ----------------------------------------------------------------------


und hier die Letzte die Help-datei.
Ist vieleicht ein bisschen schwierig aber einfach mit copy paste (kopieren ;einfügen) die dateien umbenennen und fertig.


------------------------------------------------------------------------------


--- Kurzbeschreibung:

Bat-Datei für ein Menü, um als unprivilegierter Benutzer dennoch Programme
(z.B. Systemsteuerung) als Administrator-Account zu starten.
Getestet wurde das Skript unter Windows XP.



--- Dateien dieses Paketes:

admin_menu.bat - das zu startende Skript
admin_menu.cfg - Konfigurationsdatei (Textfile)
readme.txt - diese Datei hier



--- Vorab:

(1) Ich hoffe, Sie arbeiten NICHT als Computeradministrator, geanu so wie es
Microsoft in seiner Hilfe empfiehlt.
(2) Der Dienst "Sekundäre Anmeldung" muss gestartet sein, damit der Befehl
"runas" (gehört zum Betriebssystem) arbeiten kann. Standardmässig ist dies
aber der Fall.
(3) ADMIN MEMU benötigt den Internet Explorer, um den Aufruf der Explorer.exe
zu ersetzen.



--- Installation:

Keine erforderlich: die 3 o.g. Dateien in ein Verzeichnis packen.



--- Problem: Programme als Administrator starten

Wenn man die Windows Hilfe (Start -> Hilfe & Support) aufruft, und nach
"runas" oder "Administrator" sucht, findet man die Anleitung: mit
gedrückter Umschalttaste die rechte Maustaste drücken und dann
"Ausführen als" wählen...
In Win XP geht dies auch ohne die Umschalttaste, aber na gut...

Problematisch wird es dann, wenn man mal den Explorer, die
Systemsteuerung oder andere Systemtools als Administrator benötigt.
Manches lässt sich nicht auf diese Weise starten.

Die Explorer.exe benötigt benötigt ein Flag, um mit runas ausgeführt werden
zu können und es braucht die Einstellung, den Explorer in jeweils einem
eigenen Prozess zu starten. Die Aufrufe für Dateibrowser, Systemsteurung
und Co. lassen sich oftmals(*) jedoch auch ohne Manipulation des Systems
durch Verwendung des Internet Explorers lösen.

(*) s.u.: bekannte Probleme


--- Funktionsweise/ Bedienung:

Nach Start der BAT-Datei wird der aktuelle Account geprüft, ob er
Administratorrechte besitzt. Wenn nicht, wird ein Benutzer abgefragt.
Die anschliessende Passwortabfrage stammt vom "runas" Befehl zum erneuten
Start der BAT-Datei unter dem angegebenen Benutzer. Die Eingabe erfolgt ohne
Anzeige der eingegebenen Zeichen.

Das nachfolgende Admin-Menü erscheint in einem roten Fenster, damit man eine
optische Warnung hat. Die aufgelisteten Programme werden als Administrator
gestartet (der User wird angezeigt).

Achtung:
Wenn nach dem ersten Aufruf das Menü im roten Fenster erscheint, dann
ist Ihr Benutzer ein lokaler Adminstrator. Das Skript funktioniert
gleichermassen, aber Sie sollten in Ihrem eigenen Interesse die
Benutzerberechtigungen anpassen. Mehr dazu erfahren Sie in der Windows-
Hilfe.

Zum Start eines Programmes ist das erste Zeichen einzugeben und mit [Enter]
zu bestätigen - das ist nicht so sehr komfortabel, es ist
halt nur eine Bat-Datei ;-)
Angezeigt wird der Text "starte [Programmname]" - dieser Text bleibt bis
Ende des Programmes stehen.



--- Konfiguration

Öffnen Sie "admin_menu.cfg" mit einem Texteditor Ihrer Wahl (Notepad).

(1) Administrator-Account vorgeben:
Um Tipparbeit zur der Eingabe eines Administrator-Accounts zu sparen,
kann mit der folgenden Zeile ein Benutzer vorgegeben werden:
set sAdminUser=[Benutzername]
Die Eingabe des Passwortes wird jedoch notwendig bleiben.
Auf dem heimischen PC ist das sicher unproblematisch; auf einem Firmen-PC
möchte ich von Verwendung dieser Funktionalität abraten.

(2) Programme definieren
Im darunterfolgenden Abschnitt sind die angezeigten Menü-Einträge
konfiguriert. Pro Zeile sind angegeben:
- Eingabezeichen (es können durchaus mehrere Zeichen verwendet werden)
- angezeigter Programmname im Menü
- zu startendes Kommando
Trenner ist das Zeichen : (Doppelpunkt). Wenn ein zu startendes Programm
Leerzeichen oder andere Sonderzeichen enthält, muss man es quoten - in der
Konfigurationsdatei sind je 2 "-Zeichen zu verwenden. Der Internet Explorer
ist z.B. so gequotet enthalten.

Anbei einige CLSIDs, die man als Parameter verwenden kann:
{992CFFA0-F557-101A-88EC-00DD010CCC48} DFÜ-Netzwerk
{FBF23B42-E3F0-101B-8488-00AA003E56F8} Internet Explorer
{645FF040-5081-101B-9F08-00AA002F954E} Papierkorb
{21EC2020-3AEA-1069-A2DD-08002B30309D} Systemsteuerung
{20D04FE0-3AEA-1069-A2D8-08002B30309D} Arbeitsplatz
{208D2C60-3AEA-1069-A2D7-08002B30309D} Netzwerk Nachbarschaft
{2227A280-3AEA-1069-A2DE-08002B30309D} Drucker
{00021400-0000-0000-C000-000000000046} Desktop
{00021401-0000-0000-C000-000000000046} Shortcut
{00020D75-0000-0000-C000-000000000046} PostEingang
{00028B00-0000-0000-C000-000000000046} The Microsoft Network
{450D8FBA-AD25-11D0-98A8-0800361B1103} Eigene Dateien
{D6277990-4C6A-11CF-8D87-00AA0060F5BF} Task Planer
{7BD29E00-76C1-11CF-9DD0-00A0C9034933} Temp. Internet Files
{BD84B380-8CA2-1069-AB1D-08000948F534} Schriftarten
{1A9BA3A0-143A-11CF-8350-444553540000} Favoriten



--- bekannte Probleme

Wenn der Aufruf des Internet Explorers mit diversen CLSID mit einer
Fehlermeldung quittiert wird, kann man den normalen Explorer verwenden,
indem man sich einmal unter Admin anmeldet, dort im Explorer den Befehl
"Extras/Ordneroptionen" aufruft und auf dem Register "Ansicht" die
Option "Ordnerfenster in einem eigenen Prozess starten" aktiviert.

Dann wieder als normaler Benutzer anmelden und das Admin-Menü bearbeiten:
Hier ist mal als Punkt 2 der Arbeitsplatz mit dem normalen Explorer

(...)
1:Arbeitsplatz:""%ProgramFiles%\Internet Explorer\IEXPLORE.EXE""
::{20D04FE0-3AEA-1069-A2D8-08002B30309D}
2:Arbeitsplatz:EXPLORER.EXE ::{20D04FE0-3AEA-1069-A2D8-08002B30309D}
(...)


--- EOF

diese Programme stammen von einem Herren, deren Name ich wieder suchen muss und dann hier eintragen werde.